# Dinosaur President
# First Relationship Dialogue
# Creator: Alexa Keizur/Kimberly Sheely
# Last Edited: 3-28-11 by Benson
label dinoPres_0:
    $name = myPlayer.getName()
    $DP = getNPC("dinoPres")
    $dinoPres = DP.getCharacter()
    
    show dinoPres happy at right
    show you normal at left
    
    dinoPres "As the President of the Dinosaur Nation, I am thrilled to meet with a presidential candidate from our sister country."
    show dinoPres normal
    dinoPres "I want our nations to continue being allies, %(name)s, as we have for the past twenty years."
    dinoPres "My nation believes that democracy is the key to a good government, and we would like to see Din-Robo continue its Democratic ways."
    dinoPres "Your people are happier under a democratic government than they could ever be under an authoritarian one."
    show dinoPres angry
    dinoPres "We cannot let our governments fall to the Robots."
    show dinoPres normal
    dinoPres "We are stronger together than we could ever be apart."

    menu:
        dinoPres "I will help you with your campaign, if you stand with the Dinosaur Nation against the robots."
        "I think we could be excellent allies.":
            show dinoPres happy
            dinoPres "I was hoping that would be your answer."
            dinoPres "I look forward to developing our relationship!"
            
            show you happy
            #"You are now acquainted with the leader of the Dinosaur Nation!"
            call changeRelationship("dinoPres", 1)
        
        "Sorry, but my country does not forget its robotic heritage.":
            show dinoPres angry
            dinoPres "I am sorry to hear that, %(name)s."
            show dinoPres sad
            dinoPres "I'm afraid you may doom your people and mine to an ugly fate..."
            dinoPres "Well, you still have time to change your mind..."
            dinoPres "If you do, talk to me again.  I'm sure we can work something out."
    
    jump endActivity
