# Robot Leader
# Coffee Dialogue
# Creator: Alexa Keizur/Kimberly Sheely
# Last Edited: 3-27-11 by Benson
label leadRobo_coffee:
    $ randomChoice = choice([0,1])
    
    scene bg coffeeBG with fade
    $name = myPlayer.getName()
    # Remember that this is the one that calls the methods...
    # but the call name corresponds to the renpy scene characters
    $RL = getNPC("leadRobo")
    # ... And this is the one that speaks
    $leadRobo = RL.getCharacter()
    
    show leadRobo normal at offright
    show you normal at offleft
    with None
    
    show leadRobo normal at right
    show you normal at left
    with ease
    
    if randomChoice == 0:        
        leadRobo "Greetings, %(name)s."
        
        menu:
            leadRobo "I am looking forward to our conversation."
            "I too am excited to talk to you!":
                show you happy at left 
                leadRobo "Then we should begin immediately, %(name)s."
            "I will be as soon as I get a little coffee.":
                show you tired at left 
                leadRobo "Then you must do so, so we can start."

    elif randomChoice == 1:
       
        menu:
            leadRobo "I am told that coffee has an interesting smell, %(name)s."
            "Are you not able to smell?":
                leadRobo "I can smell, but I do not experience smells in the same way you do, %(name)s."
                leadRobo "My species also has other senses which yours do not."
                "You learned something about the Robots!"
                call changeStats("intelligence", 1)
            "Yes, it is pretty strong and fragrant.":
                leadRobo "I see..."
                leadRobo "That must be why so many Robot-Dinosaurs enjoy it."

    show you normal at left with fade
    show leadRobo normal at right
    leadRobo "Social protocol indicates that we must converse now, yes?"
    $RL.doRelationship()
    
          
