label dinoPres_golf:
    $ randomChoice = choice([0,1,2])
    
    scene bg golfBG with fade
    $name = myPlayer.getName()
    $DP = getNPC("dinoPres")
    $dinoPres = DP.getCharacter()
    
    show dinoPres happy at offright
    show you normal at offleft
    with None

    show dinoPres happy at right
    show you normal at left
    with ease

    dinoPres "Why hello there, %(name)s!"
    dinoPres "Are you ready for a round of golf?"
    
    show dinoPres normal at right
    show you normal at left
    
    if randomChoice == 0:        
        dinoPres "Fore! Fore I say!"
        "*thwack*"
        "*The president's golf ball soars through the air...*"
        "..."
        show dinoPres sweat at right with fade
        "And hits a tree head on!"
        show dinoPres sad at right
        
        menu:
            dinoPres "I fear you are a much better golfer than I am, %(name)s."
            "I wouldn't say that, my ball is still in the sand.":
                show dinoPres happy at right
                dinoPres "*laughs*"
                dinoPres "Well, it's just a game, after all!"
            "You are too kind.":
                show dinoPres normal at right
                dinoPres "No need to be so modest, %(name)s, you're quite good!"
            "Of course I am!":
                show you confident at left
                show dinoPres happy at right
                dinoPres "Good to see you have some confidence in yourself!"

    elif randomChoice == 1:
        dinoPres "Another sunny day, wonderful!"

        menu:
            dinoPres "Think it's a good day for golf?"
            "Yes, let's play!":
                show dinoPres happy at right
                dinoPres "I'm going to win today, I can feel it..."
            "I think it is supposed to rain later today...":
                show dinoPres happy at right
                dinoPres "Well, I suppose we'd better enjoy the sun while it lasts!"
        show dinoPres normal at right
        dinoPres "I shall go first."
        "*thwack!*"
        "*The president's golf ball soars through the air...*"
        "..."
        show dinoPres normal at right with fade
        "Splash!"
        show dinoPres sad
        dinoPres "My ball went into the lake..."

    elif randomChoice == 2:
            show dinoPres normal at right with fade
            "*thwack!*"
            "The president's shot looks pretty good!"
            "..."
            "It's a hole in one!"
            show dinoPres happy at right
            
            menu:
                dinoPres "Yes! A hole in one!"
                "Congratulations!":
                    show you happy
                    dinoPres "Why thank you, %(name)s!"
                "Wait, that was the wrong hole...":
                    show you sweat
                    show dinoPres confused
                    dinoPres "Huh?"
                    
    show you normal at left with fade
    show dinoPres normal at right
    dinoPres "While I have your attention, there is something I would like to speak with you about..."
    $DP.doRelationship()
    
          
