label endgame:
    scene bg wakeupBG
    show planner happy at right
    show you normal at left
    
    planner "This is it!"
    planner "It's finally election time!"
    show planner normal
    planner "People have been voting all day, and the results are in!"
    
    menu:
        planner "Are you ready for the results?"
        "Bring it on!":
            show planner happy
            planner "That's the spirit!"
        "I don't think I'm ready for this...":
            show you sweat
            show planner happy
            planner "Of course you're ready!"
            planner "You've worked really hard for this."
    
    planner "Let's see..."
    planner "..."
    planner "......"
    planner "........."
    show planner happy
    planner "You won!!"
    show you happy
    you "Really!?"
    planner "We did it!"
    you "Let's celebrate!"
    
    show planner happy at offright
    show you happy at offright
    with ease
    
    
    "After a long and tough campaign, you beat out your rivals!"
    # TODO: better function here that tells you how big a margin you won by
    # ie: relationship points > something = large margin and etc..
    $ score = 0;
    $ score = npcControl.getScore()
    if score > 7:
        "It seems your victory was by a particularly large margin."
        "Looks like everyone loves you!  Sort of.  I guess."
    else:
        "It seems your victory was by a very small margin."
        "What a close election!"
    "So what did you do after you became president?"
    "..."
    
    # TODO: better function that determines your alignment
    $ score = npcControl.getAlignment()
    if score > 4:
        $ alignment = "democracy"
    elif score < -4:
        $ alignment = "authoritarian"
    else:
        $ alignment = "neutral"
    
    if alignment == "authoritarian":
        "You decided to reshape your country's government to be more
        authoritarian, with you as the head of the new system."
        "Of course, the democrats didn't like this, but many others were
        happy with your decision."
        "It looks like it's going to be peaceful around here for a while."
    elif alignment == "democracy":
        "You decided to keep your beloved country a democracy."
        "As expected, there was some protest, but nothing too bad."
        "The President of the Dinosaurs wants you to join him in a war against
        the Robots, but you haven't decided what to do about that."
        "Maybe another time."
    else:
        "You never really decided which direction to steer the country..."
        "But the people agreed that you would be a wise and fair leader."
        "You'll figure something out, right?"
    
    return 
