# Robot Leader 
# "Reverse" dialogue
# Called when you are too friendly with the dinoPres guy 
# Last edited: 4-12-11 Eric A.

label leadRobo_reverse:
    $name = myPlayer.getName()
    $RL = getNPC("leadRobo")
    $leadRobo = RL.getCharacter()
    
    show leadRobo normal at right
    show you normal at left
    
    leadRobo "I have received reports that you have been meeting with the President of the Dinosaurs, %(name)s."
    
    menu:
        leadRobo "Is this correct?"
        "That is correct.":
            show leadRobo sad
            leadRobo "That is unfortunate, %(name)s."
            show leadRobo normal
            leadRobo "I was hoping my agents were mistaken."
        "I'm still exploring my options.":
            leadRobo "Valid answer, %(name)s, but you will soon have to choose sides."
        "That's not true!":
            leadRobo "I am afraid that I am not mistaken, %(name)s."
            leadRobo "The evidence I have does not lie."
    
    leadRobo "In the future, you can not meet with both of us."
    leadRobo "Authoritarian government would do your country well, and an alliance with us robots would make us both strong, %(name)s."
    leadRobo "I cannot force you to do this.  You must choose for yourself."

label leadRobo_reverse_choice:
    menu:
        leadRobo "What will you choose?"
        "I'll abandon the President and join the Robots!":
            menu:
                leadRobo "You would join us Robots and build a new authoritarian government?"
                "Yes!":
                    leadRobo "Understood."
                    leadRobo "Wise choice, %(name)s."
                    leadRobo "We robots and robot dinosaurs will make powerful allies."
                    $RL.unReverse()
                "Wait.. hold on.":
                    leadRobo "Understood."
                    jump leadRobo_reverse_choice
        "I'm sorry, but I have to stick with the President.":
            menu:
                leadRobo "You would join the Dinosaurs instead and continue with Democracy?"
                "Yes!":
                    show leadRobo sad
                    leadRobo "Understood."
                    show leadRobo normal
                    leadRobo "Then from this day, our alliance is over."
                    leadRobo "I shall be going now."
                "Wait.. hold on.":
                    leadRobo "Understood."
                    jump leadRobo_reverse_choice
        "(Persuade) Can't we work something out with both of you?":
            $persuade = RL.persuade(myPlayer.getStats(), myPlanner.getDay())
            if persuade:
                leadRobo "Valid suggestion, %(name)s."
                show leadRobo sad
                leadRobo "..."
                show leadRobo normal
                leadRobo "For many years, we robots and dinosaurs have been enemies."
                leadRobo "Yet perhaps, with a strong leader such as yourself, we can put our past behind us."
                leadRobo "Choice confirmed.  We are expecting great things, %(name)s."
                $LR.unReverse()
            else:
                show leadRobo angry
                leadRobo "The Robots and Dinosaurs are enemies, %(name)s."
                show leadRobo normal
                leadRobo "We cannot accept that option."
                jump leadRobo_reverse_choice
            
    jump endActivity

