# Dinosaur President
# "Reverse" dialogue
# Called when you are too friendly with the leadRobo guy 
# Last edited: 4-12-11 Eric A.

label dinoPres_reverse:
    $name = myPlayer.getName()
    $DP = getNPC("dinoPres")
    $dinoPres = DP.getCharacter()
    
    show dinoPres normal at right
    show you normal at left
    
    dinoPres "I have been getting reports that you have been meeting with the Robot leader, %(name)s."
    
    menu:
        dinoPres "Is it true you've been meeting with Leader Bot 3.0?"
        "Yes, Mr. President.":
            show dinoPres sad
            dinoPres "I see..."
            show dinoPres normal
            dinoPres "I was afraid of that."
            dinoPres "Yet you are still here..."
        "I'm still exploring my options.":
            dinoPres "Wise answer, but don't forget:"
            dinoPres "It's a Democracy that is putting you into power in the first place."
        "That's not true!":
            dinoPres "Funny... It's all over the news.  I don't think you can avoid that at this point."
    
    show dinoPres sad
    dinoPres "This is unacceptable."
    show dinoPres normal
    dinoPres "You can't play both sides.  You will have to choose one."
    dinoPres "Being the well-informed leader that I am, I know for a fact that siding with the Robots will lead to your doom."
    show dinoPres angry
    dinoPres "It can only lead to bad things!"
    dinoPres "Bad!  Like war!"
    show dinoPres normal
    dinoPres "Make a choice.  Will you side with me, and join us in a glorious Democracy?"
    dinoPres "Or will you choose that... that dastardly Robot Leader?"

label dinoPres_reverse_choice:
    menu:
        dinoPres "What will you choose?"
        "I'll abandon the Robots and join the Dinosaurs!":
            menu:
                dinoPres "You'll join us Dinosaurs and support Democracy?"
                "Yes!":
                    show dinoPres happy
                    dinoPres "Wonderful!"
                    dinoPres "Simply wonderful!"
                    show dinoPres normal
                    dinoPres "That's a relief, %(name)s."
                    dinoPres "I hope we can work together to make our countries even greater!"
                    $DP.unReverse()
                "Wait.. hold on.":
                    dinoPres "Alright, let's hear it then."
                    jump dinoPres_reverse_choice
        "I'm sorry, but I have to stick with the Robots.":
            menu:
                dinoPres "You would join the Robots instead and form an Authoritarian government?"
                "Yes!":
                    show dinoPres sad
                    dinoPres "I see..."
                    show dinoPres normal
                    dinoPres "Then from this day, our alliance is over."
                    dinoPres "May we meet again under more favorable circumstances."
                "Wait.. hold on.":
                    dinoPres "Alright, let's hear it then."
                    jump dinoPres_reverse_choice
        "(Persuade) Can't we work something out with both of you?":
            $persuade = DP.persuade(myPlayer.getStats(), myPlanner.getDay())
            if persuade:
                "The President chuckles to himself."
                show dinoPres happy
                dinoPres "Haha!"
                show dinoPres normal
                dinoPres "It's been a long time since a strong leader has approached me with that idea."
                dinoPres "Good question.  Why not?"
                dinoPres "Very well!  I'll leave it in your hands, %(name)s."
                dinoPres "May we all put our past behind us for a better future!"
                $DP.unReverse()
            else:
                show dinoPres angry
                dinoPres "The Robots and Dinosaurs are enemies, %(name)s."
                show dinoPres normal
                dinoPres "I can't accept that."
                jump dinoPres_reverse_choice
            
    jump endActivity

