# Dinosaur President 
# "Reversed Still" dialogue
# Called after you've chosen a side but want to try and reconcile
# Last edited: 4-12-11 Eric A.

label dinoPres_reverseStill:
    $name = myPlayer.getName()
    $DP = getNPC("dinoPres")
    $dinoPres = RL.getCharacter()
    
    show dinoPres normal at right
    show you normal at left
    
    dinoPres "So you've returned."
    
label dinoPres_reverseStill_choice:
    menu:
        dinoPres "You already chose the Robots.  Why are you here?"
        "(Persuade) Why can't I work with both of you?":
            $persuade = DP.persuade(myPlayer.getStats(), myPlanner.getDay())
            if persuade:
                "The President chuckles to himself."
                show dinoPres happy
                dinoPres "Haha!"
                show dinoPres normal
                dinoPres "It's been a long time since a strong leader has approached me with that idea."
                dinoPres "Good question.  Why not?"
                dinoPres "Very well!  I'll leave it in your hands, %(name)s."
                dinoPres "May we all put our past behind us for a better future!"
                $DP.unReverse()
            else:
                show dinoPres sad
                dinoPres "I'm sorry.  What I said before still stands."
                show dinoPres normal
                dinoPres "Robots and Dinosaurs are enemies."
                dinoPres "Now if you're done, I have a meeting to attend."
        "I want to ally with the Dinosaurs, not the Robots!":
            menu:
                dinoPres "You'll join us Dinosaurs and support Democracy?"
                "Yes!":
                    show dinoPres happy
                    dinoPres "Wonderful!"
                    dinoPres "Simply wonderful!"
                    show dinoPres normal
                    dinoPres "That's a relief, %(name)s."
                    dinoPres "I hope we can work together to make our countries even greater!"
                    $DP.unReverse()
                "Wait.. hold on.":
                    dinoPres "Alright, let's hear it then."
                    jump dinoPres_reverseStill_choice
            
    jump endActivity

