# Pteradude
# First Relationship Dialogue
# Creator: Alexa Keizur/Kimberly Sheely

label pteradude_0:
    $name = myPlayer.getName()
    $PD = getNPC("pteradude")
    $pteradude = PD.getCharacter()
    
    show pteradude normal at right
    show you normal at left
    
    pteradude "Before we start, I guess I should probably say..."
    pteradude "Woah."
    show pteradude sweat
    pteradude "Out of all the kids at my school, I can't believed I was picked to speak with you!"
    show pteradude normal
    
    menu:
        pteradude "Well, I guess I should introduce myself to you, honorable %(name)s."
        "No need to be so formal.":
            show pteradude happy
            pteradude "Ok, I guess."
        "<Say Nothing>":
            # SUCH A HACK
            $name = "honorable " + name 
    show pteradude normal
    pteradude "Well, I am Pteradude, from the University of Dinology."
    show pteradude happy
    
    menu:
        pteradude "I major in political science, so I'm really glad I could meet you today."
        "I'm glad to talk to you too.  I value the opinion of the students of our country.":
            pteradude "You know, you're actually pretty cool."
            pteradude "I thought you might be all stern and strict, but I guess presidential candidates are just people like everyone else."
        "Yes, well, this was actually a bit of a political stunt.":
            show pteradude sweat
            pteradude "So you don't actually care about what I say, huh."
    show pteradude normal
    pteradude "Well, what i really wanted to talk to you about is what you were planning to do if you became president."
    pteradude "I have some thoughts on the direction we're heading as a country, so I was wondering if you might want to hear them?"
    show pteradude sweat
    
    menu:
        pteradude "I know we're almost out of time for this meeting, but if you wanted to meet later..."
        "Of course! I would love to hear your ideas.":
            show pteradude happy
            pteradude "Awesome!"
            pteradude "You won't regret it!"
            call changeRelationship("pteradude", 1)
        "I think it would be best if we didn't...":
            show pteradude sad
            pteradude "Yeah, I guess you don't have much time for everyone..."
            show pteradude normal
            pteradude "Well, call me up if you ever change your mind!"
    
    jump endActivity
