# Mr. Velocigramps
# Golf Dialogue
# Creator: Alexa Keizur/Kimberly Sheely
# Last Edited: 3-28-11 by Benson

label gramps_golf:
    $ randomChoice = choice([0,1])
    
    scene bg golfBG with fade
    $name = myPlayer.getName()
    # Remember that this is the one that calls the methods...
    # but the call name corresponds to the renpy scene characters
    $GR = getNPC("gramps")
    # ... And this is the one that speaks
    $gramps = GR.getCharacter()
    
    if GR.isReversed() :
        jump gramps_reverseStill
    
    show gramps normal at offright
    show you normal at offleft
    with None
    
    show gramps normal at right
    show you normal at left
    with ease

    gramps "Hello %(name)s!"
    show gramps happy
    gramps "It's a great day to be out on the golf course!"
    
    if randomChoice == 0:        
        show gramps normal at right 
        show you normal at left
        with ease
        
        gramps "Ah, ah, ah..."
        show gramps happy
        gramps "Yes!"
        
        menu:
            gramps "Best hole all game!"
            "Nice job!":
                gramps "Thank you!"
                show gramps normal
                gramps "I do love this sport, you know, I used to play at least once a week!"
            "Now I'll never catch up!":
                show gramps normal at right
                gramps "I think you still can.  Don't give up!"
                gramps "You're not half bad, if I do say so myself."

    elif randomChoice == 1:
        gramps "This reminds me of when I was on the golf team in college."
        show gramps confused
        
        menu:
            gramps "Were you ever on any sports teams?"
            "I've always been all about sports.":
                show gramps normal
                gramps "Really?"
                show gramps happy 
                gramps "Quite the sporty kind, aren't you, %(name)s?"
            "I play sports occasionally...":
                show gramps happy
                gramps "Ah, so you're like me!"
                gramps "I never did much besides golf."
            "Not really, I've never been extremely athletic.":
                show gramps normal
                gramps "Well, you're playing golf with me right now, so that's something!"

    show you normal at left with fade
    show gramps happy at right
    gramps "Thank you so much for inviting me here!"
    gramps "However, I did also want to talk to you about your campaign..."
    $GR.doRelationship()

