# President
# Coffee Dialogue
# Creator: Alexa/Kimberly
# Last Edited: 3-28-11 by Benson
label dinoPres_coffee:
    # Pick a random dialogue tree
    $ randomChoice = choice([0,1,2])
    
    scene bg coffeeBG with fade
    $name = myPlayer.getName()
    $DP = getNPC("dinoPres")
    $dinoPres = DP.getCharacter()
    
    if DP.isReversed() :
        jump dinoPres_reverseStill
        
    show dinoPres happy at offright
    show you normal at offleft
    with None
    
    show dinoPres happy at right
    show you normal at left
    with ease
    
    if randomChoice == 0:        
        dinoPres "Why hello there, %(name)s!"
        show dinoPres confused at right
        menu:
            dinoPres "You seem a bit tired, %(name)s. Are you feeling awake yet?"
            "Yes!":
                show dinoPres happy at right 
                dinoPres "Wonderful!"
            "Not quite...":
                show you tired at left 
                show dinoPres happy at right
                dinoPres "*chuckles*"
                dinoPres "It's a good thing we're getting coffee, then!"

    elif randomChoice == 1:
        dinoPres "Hello, %(name)s, over here!"
        show dinoPres confused at right
        
        $drink = ""
        menu:
            dinoPres "(Persuade) Do you know what you'll be having today?"
            "Hot chocolate!":
                $drink = "hot chocolate"
            "Coffee. Black.":
                $drink = "coffee"
            "Steamed milk, I think.":
                $drink = "steamed milk"
            "Tea is always my favorite.":
                $drink = "tea"
        $persuade = DP.persuade(myPlayer.getStats(), myPlanner.getDay())
        if persuade:
            show dinoPres happy at right
            dinoPres "That sounds excellent, %(name)s!"
            dinoPres "I shall have %(drink)s as well."
            "The president agrees with you!"
            call changeStats("charm", 1)
        else:
            show dinoPres normal at right
            dinoPres "Really?  I see."
            dinoPres "I'll go for a dinoca latte. I hear it's quite popular in my country."

    elif randomChoice == 2:
            dinoPres "Good to see you, %(name)s!"
            dinoPres "I always forget which coffee shop is which around here, your country seems to have so many."
            show dinoPres confused at right
            
            menu:
                dinoPres "Is this the one with those wonderful pistachio cupcakes?"
                "Yes, it most certainly is.":
                    show dinoPres happy at right 
                    dinoPres "Excellent!"
                "No, I believe that is a different cafe...":
                    show dinoPres sad at right
                    dinoPres "That's fine... Maybe another time then."
                "I... really have no idea":
                    show dinoPres happy at right
                    dinoPres "Well, I believe we'll find out shortly!"
                    
    show you normal at left
    show dinoPres normal at right
    with fade
    dinoPres "In any case, we did come here to talk.  Let's begin."
    $DP.doRelationship()
    
          
