# Dinosaur President
# Relationship Level 1 Dialogue
# Creator: Alexa Keizur/Kimberly Sheely
# Last Edited: 04-12-11 by Eric

label dinoPres_1:
    $name = myPlayer.getName()
    $DP = getNPC("dinoPres")
    $dinoPres = DP.getCharacter()
    
    show dinoPres normal at right
    show you normal at left
    
    dinoPres "You may have been wondering why I am interested in your campaign."
    dinoPres "After all, I am already president of a large and prosperous nation of dinosaurs."
    
    menu:
        dinoPres "Don't you think it's strange that I spend so much time with you?"
        "Well, I have been curious...":
            show dinoPres happy
            dinoPres "Well, jolly good!"
            show dinoPres normal
            dinoPres "It's for a good reason, of course."
        "I thought you just liked me.":
            show dinoPres happy
            dinoPres "Ha ha ha!"
            show dinoPres normal
            dinoPres "You are very likable, but that is not the only reason I meet with you."
        "Maybe your job is not all it's cracked up to be?":
            show dinoPres sweat
            dinoPres "Of course, my job is hard, and requires much work."
            show dinoPres normal
            dinoPres "But that's not it."
    
    dinoPres "As you know, the Robots and Dinosaurs have always had their differences."
    dinoPres "Luckily, we are both evenly matched.  In power, I mean."
    dinoPres "While we'd both like to be better than the other, we would never dare to start a war or anything like that."
    dinoPres "I'd like to think that we are the better nation, though."
    show dinoPres happy
    dinoPres "That's where you come in!"
    show dinoPres normal
    dinoPres "You and your young country have just entered the world stage."
    dinoPres "If you choose to side with either of us, you can help determine the superior nation."
    dinoPres "But of course, I can't really make you choose right now, so I'll let you think about it."
    
    "You learned something about the Dinosaurs!"
            
    call changeRelationship("dinoPres", 1)
    
    jump endActivity
