# Mr. Velocigramps
# Coffee Dialogue
# Creator: Alexa Keizur/Kimberly Sheely
# Last Edited: 3-28-11 by Eric

label gramps_coffee:
    $ randomChoice = choice([0,1])
    
    scene bg coffeeBG with fade
    $name = myPlayer.getName()
    $GR = getNPC("gramps")
    $gramps = GR.getCharacter()
    
    if GR.isReversed() :
        jump gramps_reverseStill
        
    show gramps happy at offright
    show you normal at offleft
    with None

    show gramps happy at right
    show you normal at left
    with ease
    
    gramps "Hello there, %(name)s!"
    show gramps normal
    gramps "Let's get something to drink."
    
    if randomChoice == 0:        
        gramps "I can't believe how many coffee shops there are nowadays!"
        
        menu:
            gramps "It seems like there is one on every street corner."
            "Was it different when you were young?":
                show you confused
                gramps "Of course it was, %(name)s."
                gramps "When I was young, the dinosaur robots lived in both nations, the nations of the Dinosaurs and Robots."
                gramps "I grew up with the Robots, myself, and I could sit here for hours telling you stories about the golden days..."
                gramps "But I won't."
                show gramps sad
                gramps "I still miss it sometimes..."
            "I like them, they are a good places to relax and meet with people.":
                show gramps happy
                gramps "Right you are!  Let's have a drink."

    elif randomChoice == 1:
        show gramps happy
        gramps "I always enjoy a good cup of tea in the morning."
        show gramps normal
        menu:
            gramps "It reminds me of when I was younger..."
            "Are you not happy with the present?":
               show gramps happy
               gramps "I like the present just fine!"
               show gramps normal
               gramps "Though I do think our government could make some adjustments."
            "I enjoy tea too!":
                gramps "Yes, it's just so relaxing..."
            "Tea? Gross!":
                show gramps sweat
                gramps "Well, I guess we don't have to have the same opinion about everything..."
                

    show you normal at left with fade
    show gramps normal at right
    gramps "Let's get down to business."
    gramps "I know you invited me here to talk!"
    $GR.doRelationship()
    
          
