# The game starts here.
# This is the first script file caleld when you click "Start Game".
# Creator: ?
# Last Edited: 3-28-11 by Alexa
label start:
    $ from random import *
    scene bg plannerBG with fade
    
    # Re-initialize these so that they save properly
    $ myPlanner = Planner()
    $ myPlayer = Player()
    $ npcControl = NPCController(False)

label tutorial:
    menu:
        "Hey, you!\nIs this your first time playing?"
        "Yes":
            "Ok!  Click {color=66f}anywhere{/color} on the screen!"
            "Great!  You now know how to advance the game."
            
            menu:
                "How about clicking one of these buttons again?"
                "It's a button!":
                    "Great!"
                "Another one!":
                    "Wonderful!"
        "No":
            "Great!"
            jump no_tutorial
            
label no_tutorial:
    "Remember to {color=f44}pay attention{/color} to these buttons!"
    "People will ask you {color=66f}very important questions{/color} as you play
    the game."
    
    "Good luck!"
    
    scene bg wakeupBG with fade
    show you tired at center
    "*YAAAWN*"
    "It is the start of a brand new day!"
    show you normal
    "You are a young and ambitious politician in the country of Din-Robo."
    "Your name is..."
    show you confused
    "Wait, what was your name?"
    $ name = renpy.input("Seriously, what is your name? " +
    "(Press Enter when done)").strip() 
    while (name == ""):
        $ name = renpy.input("No, it wasn't nothing... " +
        "What is your name? (Press Enter when done)").strip()
    $ myPlayer.setName(name)

    show you happy at center
    you "Ah yes, that's what it was."

    show planner normal at offright with None
    show you normal at left
    show planner normal at right
    with ease

    "Oh, it's your loyal advisor, Plannersaurus!"

    show planner happy
    planner "Good morning, %(name)s!"
    show planner normal
    planner "Have you heard the news?"
    planner "The president of Din-Robo has announced that he is officially
    stepping down!"
    show planner happy at right
    planner "This is your chance!"
    show planner happy at offright
    show you happy at center 
    with ease
    "Yes! This is your chance!" 
    show you confident at center
    "You have been waiting to run for the presidency since you were just an
    egg!"
    "You have so many visions for the future of Din-Robo!"

    show you happy at left
    show planner confused at right
    with ease
    planner "What are you doing?"
    show you normal at left
    you "Just thinking..."
    show planner normal
    planner "Come! If you want to win the presidency, you must learn what you
    need to do!"

    scene bg readingBG with fade
    show planner normal at offright with None
    show you normal at offright with None
    show you normal at left
    show planner normal at right
    with ease
    
    planner "The key to winning any election is the support of your people."
    show planner happy
    planner "If you form {color=66f}relationships{/color} with people, they will
    support you and your goals!"
    show planner normal
    planner "To form relationships with people, you need to 
    {color=66f}talk{/color} with them and do {color=66f}activities{/color}
    with them."
    planner "You also need to be able to know what they want and help them
    accomplish their goals."
    planner "If you don't support your friends, they won't be willing to
    support you!"
    
    planner "You will also need to work hard to
    {color=66f}improve yourself{/color}."
    planner "You can {color=66f}read{/color} to become more
    {color=00f}intelligent{/color},
    {color=66f}practice speeches{/color} to become more
    {color=f00}charming{/color}, and
    {color=66f}hold fundraisers{/color} to make more
    {color=0f0}money{/color}."
    planner "These traits will help you win over the people you want to
    represent!"
    
    scene bg nightBG with fade
    show you normal at offright with None
    show you normal at center
    with ease
    show you tired
    "Well, that was quite a day."
    show you happy
    "You can't wait to start campaigning tomorrow!"
    
    jump gameLoopStart             

